;ft2d1.mac
; Biosym Felix 2.3
; macro for processing the acquisition dimension (d1) of 
; Bruker DMX  2D data (digital filters)
; W. M. Westler (9/26/95)
get 'filename (no .dat extension):' datfil
get 'total number of rows collected ' nexpts  
get 'desired number of rows in matrix' nmat
get 'number of columns (Bruker size/2)'  ncols 
;get 'Left shift for digital filters ' shift
get 'DECIM (from acqus)' decim
start:
get 'Is DECIM a power of 2? (y,n)' yesno
;
; # shift points calculated from DECIM parameter in acqus file
; #points = (70.5 - 15.5/DECIM)  for DECIM a power of 2
; #points = (185/3 - 15.5/DECIM)  for DECIM not a power of 2
; cshift = trunc(points)
; Residual first order phase correction is (points-cshift) * 360 degrees
;
def bool 0
def ph0 &phase0
if &yesno eqs y then
eva points (70.5-15.5/&decim)
eva cshift (int(&points))
eva frstord (&points-&cshift)
eva correct (&frstord*360)
def phase0 &ph0
def phase1 &correct
eva bool 1
else
if &yesno eqs n then
eva points (185/3-15.5/&decim)
eva cshift (int(&points))
eva frstord (&points-&cshift)
eva correct (&frstord*360)
def phase0 &ph0
def phase1 &correct
eva bool 1
eif
eif
if &bool eq 0 start
eva zfsize (2*&ncols)
bld &datfil 2 &zfsize &nmat 0
mat &datfil w
cl
for row 1 &nexpts 
esc getout
if &getout ne 0 quit
rn &datfil
csl &cshift
def temp &datsiz
eva datsiz (&temp-&cshift)
bc .2
ss &datsiz 90
def datsiz &temp
csr &cshift
zf &zfsize
csl &cshift
ft
ph
red
sto 0 &row
ty row=&row $
next
ty
quit:
end