;HN(CO)HB for the DMX-500 (UXNMR version uxnmr)
;Quantitative J experiment for measuring couplings between C' and proton.
;Andy C. Wang and Ad Bax, March, 1995
;Original version references:
  ;Bax, et al., Meth. Enzymol. (1994) 239, 79-105.
  ;Grzesiek et al., J. Magn. Reson. (1992) 96, 215-221.
;JACS, submitted October, 1995.
;BMRB Pulse Sequence Accession Number: 34
;______________________________________________________________________
#include "bitsdmx.nt"
#define NITROGEN
#define PROTON
#define PROTON_LOOP 70
#define NITROGEN_LOOP 35
;______________________________________________________________________
;Protons on f1 (at HDO frequency):
  ;f1 = hydrogen frequency on water
  ;p1 = proton 90 @ pl1
  ;p2 = proton 90 ca 800u Watergate @ pl2
  ;p30 = proton 90 ca 50u @ pl30 using cpd1:f1
;______________________________________________________________________
;Nitrogen on f3 (at 116.5 ppm):
  ;p3  = 90 at pl3
  ;p31 = 90 at pl31 ca. 180us
  ;in20 = in21
;______________________________________________________________________
;Carbons on f2 (at 177 ppm):
  ;p5 = 58.8u      ;C' 90 @ pl5           ;null at 46ppm
  ;p6 = 26.3u      ;90 used as 180 @ pl6  ;null at 46ppm
  ;p29=614u        ;180 at 1 sp 1 @ ca. 12.4 dB w/ 2 spoffs 1 = -16464Hz
                   ;pulse program cpd2:f2
  ;in0 = 1/2sw
   d0 = in0*0.5 - p6 - p1*0.636	- 15u ; 90,-180 phase
;______________________________________________________________________
;DELAYS:
  d4=2.25m
  d5=4.6m-p30
  d3=d4-p2-250u
 ;d7 ca 100u = dw
  d11=50m
  d12=15m
  d14=18m-50u*70  ;CO-Hb dephase
  d20=13.5m
  d21=d20-5.4m-p30
  d24=p3-p6
  d26=p3-p1
;______________________________________________________________________
100u RESET
	ze
2	d11 do:f3
	d12
3	d12*3
4	d12*3
5	d12*4
6	10u do:f2
        d1 do:f1
        10u pl1:f1
        10u pl3:f3
        10u blank                         ;lock off
;___________________start 90-degree___________________
	(p1 ph10):f1
	 d4
	(d26 p1*2 ph0):f1 (p3*2 ph1):f3
	 d4
	(p1 ph1):f1
	 GRAD(10, POSITIV, 100)
	 3.5m pl29:f2
	 3.5m cpd2:f2 ;G3 mlev16 pulse decoupling of Cab (p29 @ 2 sp 1)
	(p3 ph3):f3
;___________________15N evolution_____________________
	 5.4m pl30:f1
         (p30 ph1):f1
	 d21 cpd1:f1
	 10u do:f2
	 10u pl6:f2
	(d24 p6*2 ph10):f2 (p3*2 ph8):f3 
         5u
         5u pl29:f2
	 10u cpd2:f2
	 d20
;___________________INEPT to CO______________________
	(p3 ph0):f3 
	 10u do:f2
	 10u do:f1
         (p30 ph7):f1
	 10u pl5:f2
	(p5 ph5):f2
;___________________________________________________
	 GRAD(20, POSITIV, 70)
	 d14 pl29:f2
	 10u cpd2:f2
	 7m pl1:f1
;___________________Hb evolution_____________________
	(p1 ph24):f1
	 d0
	 5u do:f2
	 10u pl6:f2
	(p6*2 ph0):f2
	 5u
         5u pl29:f2
	 5u cpd2:f2
	 d0
	(p1 ph25):f1
	 7m
	 10u do:f2
	 GRAD(30, POSITIV, 70)
   	 d14 pl5:f2
;___________________INEPT to 15N____________________
	(p5 ph0):f2 
         GRAD(40, POSITIV, 50)
         3.4m pl30:f1
         (p30 ph1):f1
	 5u cpd1:f1
	(p3 ph10):f3
;___________________________________________________
	 10m
         10u pl6:f2
	 (d24 p6*2 ph0):f2 (p3*2 ph0):f3
	 d5
         10u do:f1
        (p30 ph7):f1
	 5.4m
;___________________INEPT to Hn_____________________
	(p3 ph11):f3
	 GRAD(50, POSITIV, 30)
	 2m pl1:f1
	(p1 ph0):f1
;___________________________________________________
	 GRAD(60, NEGATIV, 5)
	 d3 pl2:f1
	(p2 ph14):f1
	 2u
	 5u pl1:f1
	(p1*2 ph0):f1
	 2u 
	 5u pl2:f1
	(p2 ph14):f1 (p3*2 ph10):f3
	 GRAD(70, NEGATIV, 5)
	 d3 pl31:f3
         go=2 ph31 cpd3:f3
10u do:f2
10u do:f1
10u do:f3
10u unblank                         ;lock on
d11 wr #0 if #0 zd
;______________________________________________________________________
#ifdef PROTON
d12 ip24
lo to 3 times 2
d12 id0
d12 ip31
d12 ip31
lo to 4 times PROTON_LOOP
#else
d12*4
#endif
;______________________________________________________________________
#ifdef NITROGEN
d12 rd0
d12 rp24
d12 ip3
lo to 5 times 2
d12 id21
d12 dd20
d12 ip31
d12 ip31
lo to 6 times NITROGEN_LOOP
#endif
;______________________________________________________________________
exit
;______________________________________________________________________
ph0=0
ph1=1
ph3=0
ph5=0 0 2 2
ph7=3
ph8=0 1 2 3
ph10=0
ph11=0 0 0 0 2 2 2 2
ph14=(3600) 1836      ;adjust for power level hl2 
ph24=0
ph25=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
;______________________________________________________________________
#ifndef PROTON
ph31=0 2 2 0 2 0 0 2
#else
ph31=0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0
#endif
;______________________________________________________________________
;Minimal phase cycle to avoid artifacts.
;______________________________________________________________________