#
# This file contains the files:
#     ccnoesy4d.fa 
#     faccnoesy4d.r 
#     Gradfa.incl 
#
# To unbundle, sh this file
#
echo ccnoesy4d.fa 1>&2
cat >ccnoesy4d.fa <<'End of ccnoesy4d.fa'
;ccnoesy4d.fa
;4D (13C,13C)-HMQC-NOESY-HSQC
;Vuister et al., J. Magn. Reson. B101, 210-213 (1993)
;Avance/Xwin-nmr version
;Written up by F. Abildgaard, NMRFAM (abild@nmrfam.wisc.edu) 
;Version: 041195, 101295
;  Disclaimer: This pulse program is provided "as is" for your 
;  information. Support for the use of this pulse program is only 
;  provided to users of the National Magnetic Resonance Facility 
;  at Madison (NMRFAM). Users of this pulse program employ it at 
;  their own risk. Neither NMRFAM or University of Wisconsin-Madison 
;  are liable for any physical or other damage incurred during the
;  use of this pulse program.
;BMRB Pulse Sequence Accession Number: 19
;
;f2: 15N, f3: 13C, f4: 13C' (optional)
;use grdprog faccnoesy4d
;use cpdprog waltz16sel4 for optional SEDUCE1 C' decoupling
;p15=500u
;p16=2.0m
;p17=4.0m
;p18=1.0m
;d2=1.7m
;d8=150m (mixing time)
;d9=10m (ip, id, rd)
;d11=100m (disk i/o)
;d12=10u
;d13=5u
;d16=300u
;d10=3u
;cnst21 8G/cm, cnst22 7G/cm, cnst23 7G/cm
;cnst24 -8G/cm, cnst25 -10G/cm, cnst26 15G/cm

"d18=(d8-p16-p17)/2"
"d22=d2-p15"
"d23=d2-p3*4-d10*2-6u"
"d29=p3-p1"

#include <Avance.incl>
#include <Gradfa.incl>

;#define SEDUCE
#undef SEDUCE

#define SED_ON d13 \n d12 pl0:f4 \n d13 cpds4:f4

#define SED_OFF d13 do:f4 \n d12 pl4:f4


1 ze
2 d11 do:f3
  d9*2
3 d9
  d9*2
4 d9
  d9
5 d9
  d9*2
6 d9
  d9
7 d9
  d9*2
8 20u LOCKH_OFF
  d1 pl1:f1 pl3:f3
  20u LOCKH_ON
  (p1 ph11):f1
  d13
  GRADIENT15(cnst21)
  d22
  d2
#ifdef SEDUCE
  SED_ON
#endif
  (p3 ph12):f3
  d0 
  (p1*2 ph0):f1
  d0 
  (p3 ph0):f3
#ifdef SEDUCE
  SED_OFF
  d13
#endif
  d13
  GRADIENT15(cnst21)
  d22
  d23
  d10
  (p3 ph1):f3
  3u
  (p3*2 ph0):f3
  3u
  (p3 ph1):f3
  d10
  (p1 ph0):f1
  d13
  GRADIENT16(cnst22)
  d18
  (p3 ph0):f3
  d13
  GRADIENT17(cnst23)
  d18
  (p1 ph0):f1
  d13
  GRADIENT15(cnst24)
  d22
  (d29 p1*2 ph0):f1 (p3*2 ph0):f3
  d13
  GRADIENT15(cnst24)
  d22 
  (p1*55 ph0):f1
  (p1 ph1):f1
  d13
  GRADIENT18(cnst25)
  d16
#ifdef SEDUCE
  SED_ON
#endif
  (p3 ph13):f3
  d20 
  (p1*2 ph0):f1
  d20 
  (p3 ph0):f3
#ifdef SEDUCE
  SED_OFF
#endif
  d13
  GRADIENT18(cnst26)
  d16
  (p1 ph0):f1
  d13
  GRADIENT15(cnst21)
  d22
  (d29 p1*2 ph0):f1 (p3*2 ph0):f3 
  d13
  GRADIENT15(cnst21)
  d22 pl16:f3
  (p21 ph2):f1
  go=2 ph31 cpd3:f3
  d11 do:f3 wr #0 if #0 zd
  d9 ip11
  d9 ip11
  lo to 3 times 2
  d9 id10
  d9 ip31
  d9 ip31
  lo to 4 times l4   ;no of complex points in t2
  d9 rd10
  d9 ip12 
  lo to 5 times 2
  d9 id0 
  d9 ip31
  d9 ip31
  lo to 6 times l6   ;no of complex points in t1
  d9 rd0 
  d9 ip13 rd10 
  lo to 7 times 2
  d9 id20 
  d9 ip31
  d9 ip31
  lo to 8 times l8   ;no of complex points in t3
  20u LOCKH_OFF
exit

ph0=0
ph1=1
ph2=2
ph3=3
ph11=(8) 1
ph12=0 2
ph13=0 
ph31=0 2 
End of ccnoesy4d.fa
echo faccnoesy4d.r 1>&2
cat >faccnoesy4d.r <<'End of faccnoesy4d.r'
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p16 { (0) | (0) | (0)+(cnst22) }
    { (0) | (0) | (0)          }
p17 { (0) | (0) | (0)+(cnst23) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst24) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst24) }
    { (0) | (0) | (0)          }
p18 { (0) | (0) | (0)+(cnst25) }
    { (0) | (0) | (0)          }
p18 { (0) | (0) | (0)+(cnst26) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
p15 { (0) | (0) | (0)+(cnst21) }
    { (0) | (0) | (0)          }
End of faccnoesy4d.r
echo Gradfa.incl 1>&2
cat >Gradfa.incl <<'End of Gradfa.incl'
;Gradfa.incl  -  include file for Gradient Spectroscopy
;avance-version
;version 94/06/27


#define GRADIENT15(ampl) p15:ngrad:c34
#define GRADIENT16(ampl) p16:ngrad:c34
#define GRADIENT17(ampl) p17:ngrad:c34
#define GRADIENT18(ampl) p18:ngrad:c34
#define GRADIENT19(ampl) p19:ngrad:c34
#define GRADIENT20(ampl) p20:ngrad:c34


#define BLKGRAD  setnmr2^0 setnmr0^34

#define UNBLKGRAD setnmr2|0 setnmr0|34

#define BLKGRAMP setnmr0^34

#define UNBLKGRAMP setnmr0|34

End of Gradfa.incl